# Maintainer:  Peter Mattern <pmattern at arcor dot de>
# Contributor: Koscheev "Ashen" Mikhail <fresh19991 at yandex dot ru>
# Contributor: Pascal "hardfalcon" Ernster <aur at hardfalcon dot net>
# Contributor: Marcel Dykstra <marcel dot dykstra at gmail dot com>

_pkgname=xf86-video-savage
pkgname=$_pkgname-git
pkgver=2.4.1.r0.g129baf3
pkgrel=1
pkgdesc='Open Source X driver for VIA IGPs'
arch=('i686' 'x86_64')
url='http://xorg.freedesktop.org/'
license=('custom')
depends=('libdrm' 'xorg-server')
optdepends=('savage-dri')
makedepends=('git' 'xorg-server-devel')
provides=("$_pkgname")
conflicts=("$_pkgname" 'X-ABI-VIDEODRV_VERSION<23' 'X-ABI-VIDEODRV_VERSION>=26')
source=("git+https://gitlab.freedesktop.org/xorg/driver/xf86-video-savage.git")
sha256sums=("SKIP")
options=(!emptydirs !strip)

pkgver() {
    cd $_pkgname
    git describe --long --abbrev=7 | sed 's/^xf86.video.savage.//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    export CFLAGS=${CFLAGS/-fno-plt}
    export CXXFLAGS=${CXXFLAGS/-fno-plt}
    export LDFLAGS=${LDFLAGS/-Wl,-z,now}

    cd $_pkgname
    ./autogen.sh --prefix=/usr
    make
}

package() {
    cd $_pkgname
    export CFLAGS=${CFLAGS/-fno-plt}
    export CXXFLAGS=${CXXFLAGS/-fno-plt}
    export LDFLAGS=${LDFLAGS/,-z,now}
    make DESTDIR=$pkgdir install
    install -D -m644 $srcdir/$_pkgname/COPYING \
      $pkgdir/usr/share/licenses/$pkgname/LICENSE
}